Use Terraform to temporarily disable the automatic primary/secondary switchover feature

Resources

Temporarily disable the automatic primary/secondary switchover feature

By default, the automatic primary/secondary switchover feature is enabled for an RDS instance that runs RDS High-availability Edition. You can use Terraform to temporarily disable the feature.

1. Create a working directory and a configuration file named main.tf in the directory. Copy the following code to the main.tf configuration file:

   • Create the required resources.

     variable "region" {
       default = "cn-heyuan"
     }
     
     provider "alicloud" {
       region = var.region
     }
     
     variable "zone_id" {
       default = "cn-heyuan-b"
     }
     
     variable "instance_type" {
       default = "pg.n2.2c.2m"
     }
     
     # Create a VPC.
     resource "alicloud_vpc" "main" {
       vpc_name   = "alicloud"
       cidr_block = "172.16.0.0/16"
     }
     
     # Create a vSwitch.
     resource "alicloud_vswitch" "main" {
       vpc_id     = alicloud_vpc.main.id
       cidr_block = "172.16.192.0/20"
       zone_id    = var.zone_id
     }
     
     # Create an RDS instance.
     resource "alicloud_db_instance" "instance" {
       engine               = "PostgreSQL"
       engine_version       = "13.0"
       instance_type        = var.instance_type
       instance_storage     = "30"
       instance_charge_type = "Postpaid"
       vswitch_id           = alicloud_vswitch.main.id
     }

   • In the main.tf file, add the resource "time_static" "example" {} configuration item and add the ha_config and manual_ha_time fields to the resource "alicloud_db_instance" "instance" {} configuration item. Then, configure the fields based on the following code snippet:

     ...
     resource "time_static" "example" {}
     
     # Create an RDS instance.
     resource "alicloud_db_instance" "instance" {
       
       # Temporarily disable the automatic primary/secondary switchover feature. Make sure that the value of the manual_ha_time field is later than the current time.
       ha_config            = "Manual"
       manual_ha_time       = formatdate("YYYY-MM-DD'T'hh:mm:ss'Z'", timeadd(time_static.example.rfc3339, "1h"))
     }

   Note

   1. The display time in the ApsaraDB RDS console is in UTC+8. If you want to use Terraform to configure a point in time, you must configure the point in time in UTC. In this example, the point in time is set to 09:00, which specifies 17:00 (UTC+8).

   2. The value of the manual_ha_time field must be later than the current time.

2. Run the following command to initialize the runtime environment for Terraform:

   terraform init

   If the following information is returned, Terraform is initialized.

   Initializing the backend...
   
   Initializing provider plugins...
   - Checking for available provider plugins...
   - Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
   ...
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other

3. Create an execution plan and preview the changes.

   terraform plan

4. Run the following command to create the resources:

   terraform apply

   During the execution, enter yes as prompted and press the Enter key. Wait until the command is successfully executed. If the following information appears, the operation is successful:

   alicloud_db_instance.instance: Modifying... [id=pgm-****]
   alicloud_db_instance.instance: Still modifying... [id=pgm-****, 10s elapsed]
   ...
   alicloud_db_instance.instance: Still modifying... [id=pgm-****, 3m0s elapsed]
   alicloud_db_instance.instance: Modifications complete after 3m4s [id=pgm-****]
   Apply complete!  Resources: 0 added, 1 changed, 0 destroyed.

5. Verify the result.

   Run the terraform show command

   Log on to the ApsaraDB RDS console

   Run the following command to view the status of the automatic primary/secondary switchover feature:

   # alicloud_db_instance.instance:
   resource "alicloud_db_instance" "instance" {
       client_ca_enabled          = 0
       client_crl_enabled         = 0
       connection_string          = "pgm-****.pg.rds.aliyuncs.com"
       connection_string_prefix   = "pgm-****"
       db_instance_storage_type   = "cloud_essd"
       db_time_zone               = "Asia/Shanghai"
       deletion_protection        = false
       engine                     = "PostgreSQL"
       engine_version             = "13.0"
       force_restart              = false
       ha_config                  = "Manual"
       id                         = "pgm-****"
       instance_charge_type       = "Postpaid"
       instance_name              = "terraformtest"
       instance_storage           = 50
       instance_type              = "pg.n2.2c.2m"
       maintain_time              = "05:00Z-06:00Z"
       manual_ha_time             = "2024-11-30T09:00:00Z"
       monitoring_period          = 300
       period                     = 0
       port                       = "5432"
       private_ip_address         = "192.168.XX.XX"
       resource_group_id          = "rg-****"
       security_group_ids         = []
       security_ip_mode           = "normal"
       security_ips               = [
           "127.0.0.1",
       ]
       sql_collector_config_value = 30
       sql_collector_status       = "Disabled"
       storage_auto_scale         = "Enable"
       storage_threshold          = 30
       storage_upper_bound        = 100
       target_minor_version       = "rds_postgres_1300_20220830"
       tcp_connection_type        = "SHORT"
       vpc_id                     = "vpc-****"
       vswitch_id                 = "vsw-****"
       zone_id                    = "cn-heyuan-b"
   
       pg_hba_conf {
           address     = "127.0.0.1"
           database    = "all"
           method      = "md5"
           priority_id = 1
           type        = "host"
           user        = "all"
       }
   }

   Log on to the ApsaraDB RDS console to view the status of the automatic primary/secondary switchover feature.

Clear resources

If you no longer require the preceding resources that are created or managed by using Terraform, run the following command to release the resources. For more information about the terraform destroy command, see Common commands.

terraform destroy

variable "region" {
  default = "cn-heyuan"
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

provider "alicloud" {
  region = var.region
}

# Create a VPC.
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# Create a vSwitch.
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

resource "time_static" "example" {}

# Create an RDS instance.
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
  # Temporarily disable the automatic primary/secondary switchover feature. Make sure that the value of the manual_ha_time field is later than the current time.
  ha_config            = "Manual"
  manual_ha_time       = formatdate("YYYY-MM-DD'T'hh:mm:ss'Z'", timeadd(time_static.example.rfc3339, "1h"))
}                       

If you want to view more complete examples, visit the directory of the corresponding service on the More Complete Examples page.