Use Terraform to upgrade the database engine version of an ApsaraDB RDS for PostgreSQL instance - ApsaraDB RDS

This topic describes how to use Terraform to upgrade the database version of an ApsaraDB RDS for PostgreSQL instance.

Note

You can run the sample code in this topic with a few clicks. For more information, visit Terraform Explorer.

Prerequisites

An RDS instance is created. For more information, see Create an RDS instance.
The RDS instance is in the Running state. You can use one of the following methods to check whether the RDS instance is in the Running state:
- Check the value of the status parameter by following the instructions provided in Query instance details. If the value is Running, the RDS instance is in the Running state.
- Log on to the ApsaraDB RDS console, switch to the required region, find the RDS instance, and then check the instance status.
An Alibaba Cloud account has all permissions on resources within the account. If an Alibaba Cloud account is leaked, the resources are exposed to major risks. We recommend that you use a Resource Access Management (RAM) user and create an AccessKey pair for the RAM user. For more information, see Create a RAM user and Create an AccessKey pair.

You must use RAM to manage access permissions on cloud resources in an efficient manner. This helps meet the requirements for multi-user collaboration and allows you to grant permissions to users based on the principle of least privilege (PoLP) to prevent security vulnerabilities caused by excessive permissions. For more information, see Grant permissions to RAM users.

{
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Action": "rds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "dbs:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:rds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Effect": "Allow",
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "backupencryption.rds.aliyuncs.com"
                    ]
                }
            }
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        }
    ]
}

The Terraform environment is prepared. You can use one of the following methods to use Terraform:
- Use Terraform in Terraform Explorer: Alibaba Cloud provides Terraform Explorer, an online runtime environment for Terraform. You can use Terraform after you log on to Terraform Explorer without the need to install Terraform. For more information, see Use Terraform in Terraform Explorer. This method is suitable for scenarios in which you want to use and debug Terraform in a fast and convenient manner at no additional cost.
- Use Terraform in Cloud Shell: Terraform is preinstalled in Cloud Shell and identity credentials are configured. You can directly run Terraform commands in Cloud Shell. For more information, see Use Terraform in Cloud Shell. This method is suitable for scenarios in which you want to use and debug Terraform in a fast and convenient manner at low cost.
- Install and configure Terraform on your on-premises machine: This method is suitable for scenarios in which network conditions are poor or a custom development environment is used. For more information, see Install and configure Terraform in the local PC.

Resources

Note

You are charged for specific resources. If you no longer require the resources, you must release or unsubscribe from the resources at the earliest opportunity.

alicloud_vpc: creates a virtual private cloud (VPC).
alicloud_vswitch: creates a vSwitch for a VPC.
alicloud_db_instance: creates an RDS instance.

Update the minor engine version

This section describes how to update the minor engine version of an RDS instance from rds_postgres_1300_20240229 to rds_postgres_1300_20240830.

Create a working directory and a configuration file named main.tf in the directory. Copy the following code to the main.tf configuration file:

Create the required resources.

variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

variable "target_minor_version" {
  default = "rds_postgres_1300_20240229"
}

# Create a VPC.
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# Create a vSwitch.
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# Create an RDS instance with the default minor engine version of rds_postgres_1300_20240229.
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
  target_minor_version = var.target_minor_version
}

Modify the target_minor_version field in the resource "alicloud_db_instance" "instance" {} configuration item.

...
resource "alicloud_db_instance" "instance" {
...
  target_minor_version = "rds_postgres_1300_20220830"
}

Note

The following list describes the minor engine version:

rds: RDS instance.
postgres: PostgreSQL database.
1300: the major engine version of PostgreSQL, which is 13 in this example.
20240229: the version of AliPG. You can select 20240530 or later. For more information about minor engine versions, see Release notes for AliPG.

Run the following command to initialize the runtime environment for Terraform:

terraform init

If the following information is returned, Terraform is initialized.

Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

Create an execution plan and preview the changes.
```
terraform plan
```

Run the following command to create the resources:

terraform apply

During the execution, enter yes as prompted and press the Enter key. Wait until the command is successfully executed. If the following information appears, the operation is successful:

alicloud_db_instance.instance: Modifying... [id=pgm-****]
alicloud_db_instance.instance: Still modifying... [id=pgm-****, 10s elapsed]
......
alicloud_db_instance.instance: Still modifying... [id=pgm-****, 4m0s elapsed]
alicloud_db_instance.instance: Modifications complete after 4m1s [id=pgm-***]

Apply complete!  Resources: 0 added, 1 changed, 0 destroyed.

Verify the result.

Run the terraform show command

Log on to the ApsaraDB RDS console

Run the following command to query the minor engine version of an RDS instance:

terraform show

# alicloud_db_instance.instance:
resource "alicloud_db_instance" "instance" {
    client_ca_enabled          = 0
    client_crl_enabled         = 0
    connection_string          = "pgm-****.pg.rds.aliyuncs.com"
    connection_string_prefix   = "pgm-****"
    db_instance_storage_type   = "cloud_essd"
    db_time_zone               = "Asia/Shanghai"
    deletion_protection        = false
    engine                     = "PostgreSQL"
    engine_version             = "13.0"
    force_restart              = false
    ha_config                  = "Auto"
    id                         = "pgm-****"
    instance_charge_type       = "Postpaid"
    instance_name              = "terraformtest"
    instance_storage           = 50
    instance_type              = "pg.n2.2c.2m"
    maintain_time              = "05:00Z-06:00Z"
    monitoring_period          = 300
    period                     = 0
    port                       = "5432"
    private_ip_address         = "172.16.XX.XX"
    resource_group_id          = "rg-****"
    security_group_ids         = []
    security_ip_mode           = "normal"
    security_ips               = [
        "127.0.0.1",
    ]
    sql_collector_config_value = 30
    sql_collector_status       = "Disabled"
    storage_auto_scale         = "Enable"
    storage_threshold          = 30
    storage_upper_bound        = 100
    target_minor_version       = "rds_postgres_1300_20220830"
    tcp_connection_type        = "SHORT"
    vpc_id                     = "vpc-****"
    vswitch_id                 = "vsw-****"
    zone_id                    = "cn-heyuan-j"

    pg_hba_conf {
        address     = "127.0.0.1"
        database    = "all"
        method      = "md5"
        priority_id = 1
        type        = "host"
        user        = "all"
    }
}

Log on to the ApsaraDB RDS console to view the minor engine version of an RDS instance.

Upgrade the major engine version

This section describes how to upgrade the major engine version of the RDS instance named pgm-**** from PostgreSQL 13 to PostgreSQL 14.

In the main.tf file, add the resource "alicloud_rds_upgrade_db_instance" "upgrade" {} configuration item.

resource "alicloud_rds_upgrade_db_instance" "upgrade" {
  source_db_instance_id    = alicloud_db_instance.instance.id
  target_major_version     = "14.0"
  db_instance_class        = "pg.n2.2c.2m"
  db_instance_storage      = "50"
  instance_network_type    = "VPC"
  db_instance_storage_type = "cloud_essd"
  collect_stat_mode        = "After"
  switch_over              = "false"
  payment_type             = "PayAsYouGo"
  vswitch_id               = alicloud_vswitch.main.id
}

Run the following command:

terraform apply

During the execution, enter yes as prompted and press the Enter key. Wait until the command is successfully executed. If the following information appears, the operation is successful:

alicloud_rds_upgrade_db_instance.upgrade: Creating...
alicloud_rds_upgrade_db_instance.upgrade: Still creating... [10s elapsed]
...
alicloud_rds_upgrade_db_instance.upgrade: Still creating... [23m41s elapsed]
alicloud_rds_upgrade_db_instance.upgrade: Creation complete after 23m51s [id=pgm-****]

Apply complete!  Resources: 1 added, 0 changed, 0 destroyed.

Verify the result.

Run the terraform show command

Log on to the ApsaraDB RDS console

Run the following command to query the RDS instance that you upgrade:

terraform show

# alicloud_rds_upgrade_db_instance.upgrade:
resource "alicloud_rds_upgrade_db_instance" "upgrade" {
    collect_stat_mode        = "After"
    connection_string        = "pgm-****.pg.rds.aliyuncs.com"
    db_instance_class        = "pg.n2.2c.2m"
    db_instance_description  = "Upgrade from pgm-****"
    db_instance_storage      = 50
    db_instance_storage_type = "cloud_essd"
    deletion_protection      = false
    engine                   = "PostgreSQL"
    engine_version           = "14.0"
    ha_mode                  = "RPO"
    id                       = "pgm-****"
    instance_network_type    = "VPC"
    maintain_time            = "18:00Z-22:00Z"
    payment_type             = "PayAsYouGo"
    port                     = "5432"
    private_ip_address       = "172.16.XX.XX"
    security_ips             = [
        "127.0.0.1",
    ]
    source_db_instance_id    = "pgm-****"
    switch_over              = "false"
    sync_mode                = "Async"
    target_major_version     = "14.0"
    tcp_connection_type      = "LONG"
    vpc_id                   = "vpc-****"
    vswitch_id               = "vsw-****"
    zone_id                  = "cn-heyuan-b"
}

Log on to the ApsaraDB RDS console to view the RDS instance that you upgrade. 账号信息

Clear resources

If you no longer require the preceding resources that are created or managed by using Terraform, run the following command to release the resources. For more information about the terraform destroy command, see Common commands.

terraform destroy

Complete sample code

Note

You can run the sample code in this topic with a few clicks. For more information, visit Terraform Explorer.

Sample code

variable "region" {
  default = "cn-heyuan"
}

provider "alicloud" {
  region = var.region
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

variable "target_minor_version" {
  default = "rds_postgres_1300_20240229"
}

# Create a VPC.
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# Create a vSwitch.
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# Create an RDS instance.
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
  target_minor_version = var.target_minor_version
  # Update the minor engine version of the RDS instance.
  # target_minor_version = "rds_postgres_1300_20240830"
}

# Upgrade the major engine version of the RDS instance.
#resource "alicloud_rds_upgrade_db_instance" "upgrade" {
#  source_db_instance_id    = alicloud_db_instance.instance.id
#  target_major_version     = "14.0"
#  db_instance_class        = "pg.n2.2c.2m"
#  db_instance_storage      = "50"
#  instance_network_type    = "VPC"
#  db_instance_storage_type = "cloud_essd"
#  collect_stat_mode        = "After"
#  switch_over              = "false"
#  payment_type             = "PayAsYouGo"
#  vswitch_id               = alicloud_vswitch.main.id
#}

If you want to experience more examples, go to the quickstarts page and view the examples in the folder of the corresponding service.