Use Terraform to manage a read-only ApsaraDB RDS for PostgreSQL instance

Updated at: 2025-01-26 05:21

This topic describes how to use Terraform to create a read-only ApsaraDB RDS for PostgreSQL instance.

Note

You can run the sample code in this topic with a few clicks. For more information, visit Terraform Explorer.

Prerequisites

  • An RDS instance is created. For more information, see Create an RDS instance.

  • The RDS instance is in the Running state. You can use one of the following methods to check whether the RDS instance is in the Running state:

    • Check the value of the status parameter by following the instructions provided in Query instance details. If the value is Running, the RDS instance is in the Running state.

    • Log on to the ApsaraDB RDS console, switch to the required region, find the RDS instance, and then check the instance status.

  • An Alibaba Cloud account has all permissions on resources within the account. If an Alibaba Cloud account is leaked, the resources are exposed to major risks. We recommend that you use a Resource Access Management (RAM) user and create an AccessKey pair for the RAM user. For more information, see Create a RAM user and Create an AccessKey pair.

  • You must use RAM to manage access permissions on cloud resources in an efficient manner. This helps meet the requirements for multi-user collaboration and allows you to grant permissions to users based on the principle of least privilege (PoLP) to prevent security vulnerabilities caused by excessive permissions. For more information, see Grant permissions to RAM users.

    {
        "Version": "1",
        "Statement": [
            {
                "Effect": "Allow",
                "Action": [
                    "vpc:DescribeVpcAttribute",
                    "vpc:DescribeRouteTableList",
                    "vpc:DescribeVSwitchAttributes",
                    "vpc:DeleteVpc",
                    "vpc:DeleteVSwitch",
                    "vpc:CreateVpc",
                    "vpc:CreateVSwitch"
                ],
                "Resource": "*"
            },
            {
                "Action": "rds:*",
                "Resource": "*",
                "Effect": "Allow"
            },
            {
                "Action": "dbs:*",
                "Resource": "acs:rds:*:*:*",
                "Effect": "Allow"
            },
            {
                "Action": "hdm:*",
                "Resource": "acs:rds:*:*:*",
                "Effect": "Allow"
            },
            {
                "Action": "dms:LoginDatabase",
                "Resource": "acs:rds:*:*:*",
                "Effect": "Allow"
            },
            {
                "Effect": "Allow",
                "Action": "ram:CreateServiceLinkedRole",
                "Resource": "*",
                "Condition": {
                    "StringEquals": {
                        "ram:ServiceName": [
                            "backupencryption.rds.aliyuncs.com"
                        ]
                    }
                }
            },
            {
                "Effect": "Allow",
                "Action": "bss:ModifyAgreementRecord",
                "Resource": "*"
            },
            {
                "Effect": "Allow",
                "Action": [
                    "bss:DescribeOrderList",
                    "bss:DescribeOrderDetail",
                    "bss:PayOrder",
                    "bss:CancelOrder"
                ],
                "Resource": "*"
            }
        ]
    }
  • Prepare the Terraform environment. You can use one of the following methods to use Terraform:

    • Use Terraform in Terraform Explorer: Alibaba Cloud provides Terraform Explorer, an online runtime environment for Terraform. You can use Terraform after you log on to Terraform Explorer without the need to install Terraform. For more information, see Use Terraform in Terraform Explorer. This method is suitable for scenarios in which you want to use and debug Terraform in a fast and convenient manner at no additional cost.

    • Use Terraform in Cloud Shell: Terraform is preinstalled in Cloud Shell and identity credentials are configured. You can directly run Terraform commands in Cloud Shell. For more information, see Use Terraform in Cloud Shell. This method is suitable for scenarios in which you want to use and debug Terraform in a fast and convenient manner at low cost.

    • Install and configure Terraform on your on-premises machine: This method is suitable for scenarios in which network conditions are poor or a custom development environment is used. For more information, see Install and configure Terraform in the local PC.

Resources

Note

You are charged for specific resources. If you no longer require the resources, you must release or unsubscribe from the resources at the earliest opportunity.

Create a read-only RDS instance

This section describes how to create a read-only RDS instance.

  1. Create a working directory and a configuration file named main.tf in the directory. Copy the following code to the main.tf configuration file:

    • Create the required resources.

      variable "region" {
        default = "cn-heyuan"
      }
      
      variable "name" {
        default = "tf-example"
      }
      
      variable "zone_id" {
        default = "cn-heyuan-b"
      }
      
      variable "instance_type" {
        default = "pg.n2.2c.2m"
      }
      
      variable "instance_type_readonly" {
        default = "pgro.n4.2c.1m"
      }
      
      provider "alicloud" {
        region = var.region
      }
      
      # Create a VPC.
      resource "alicloud_vpc" "main" {
        vpc_name   = "alicloud"
        cidr_block = "172.16.0.0/16"
      }
      
      # Create a vSwitch.
      resource "alicloud_vswitch" "main" {
        vpc_id     = alicloud_vpc.main.id
        cidr_block = "172.16.192.0/20"
        zone_id    = var.zone_id
      }
      
      # Create an RDS instance.
      resource "alicloud_db_instance" "instance" {
        engine               = "PostgreSQL"
        engine_version       = "13.0"
        instance_type        = var.instance_type
        instance_storage     = "30"
        instance_charge_type = "Postpaid"
        vswitch_id           = alicloud_vswitch.main.id
      }
    • In the main.tf file, add the resource "alicloud_db_readonly_instance" "default" {} configuration item and configure the configuration item based on the following code snippet:

      # Create a read-only RDS instance.
      resource "alicloud_db_readonly_instance" "default" {
        master_db_instance_id = alicloud_db_instance.instance.id
        zone_id               = alicloud_db_instance.instance.zone_id
        engine_version        = alicloud_db_instance.instance.engine_version
        instance_type         = var.instance_type_readonly
        instance_storage      = "50"
        instance_name         = "${alicloud_db_instance.instance.id}ro"
        vswitch_id            = alicloud_vswitch.main.id
      }
  2. Run the following command to initialize Terraform:

    terraform init

    If the following information is returned, Terraform is initialized.

    Initializing the backend...
    
    Initializing provider plugins...
    - Checking for available provider plugins...
    - Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
    ...
    
    You may now begin working with Terraform. Try running "terraform plan" to see
    any changes that are required for your infrastructure. All Terraform commands
    should now work.
    
    If you ever set or change modules or backend configuration for Terraform,
    rerun this command to reinitialize your working directory. If you forget, other
    commands will detect it and remind you to do so if necessary.
  3. Create an execution plan and preview the changes.

    terraform plan
  4. Run the following command to create the resources:

    terraform apply

    During the execution, enter yes as prompted and press the Enter key. Wait until the command is successfully executed. If the following information appears, the operation is successful:

    alicloud_db_readonly_instance.default: Creating...
    alicloud_db_readonly_instance.default: Still creating... [10s elapsed]
    ...
    alicloud_db_readonly_instance.default: Still creating... [15m11s elapsed]
    alicloud_db_readonly_instance.default: Creation complete after 15m15s [id=pgr-****]
    
    Apply complete!  Resources: 1 added, 0 changed, 0 destroyed.
  5. Verify the result.

    Run the terraform show command
    Log on to the ApsaraDB RDS console

    Run the following command to view the read-only RDS instance:

    terraform show
    ...
    # alicloud_db_readonly_instance.default:
    resource "alicloud_db_readonly_instance" "default" {
        client_ca_enabled     = 0
        client_crl_enabled    = 0
        connection_string     = "pgr-****.pg.rds.aliyuncs.com"
        deletion_protection   = false
        engine                = "PostgreSQL"
        engine_version        = "13.0"
        force_restart         = false
        id                    = "pgr-****"
        instance_name         = "pgm-****"
        instance_storage      = 50
        instance_type         = "pgro.n4.2c.1m"
        master_db_instance_id = "pgm-****"
        port                  = "5432"
        resource_group_id     = "rg-****"
        ssl_enabled           = 0
        target_minor_version  = "rds_postgres_1300_20220830"
        vswitch_id            = "vsw-****"
        zone_id               = "cn-heyuan-b"
    }

    Log on to the ApsaraDB RDS console to view the read-only RDS instance.绑定标签

Clear resources

If you no longer require the preceding resources that are created or managed by using Terraform, run the following command to release the resources. For more information about the terraform destroy command, see Common commands.

terraform destroy

Complete sample code

Note

You can run the sample code in this topic with a few clicks. For more information, visit Terraform Explorer.

Sample code

variable "region" {
  default = "cn-heyuan"
}

variable "name" {
  default = "tf-example"
}

variable "zone_id" {
  default = "cn-heyuan-b"
}

variable "instance_type" {
  default = "pg.n2.2c.2m"
}

provider "alicloud" {
  region = var.region
}

# Create a VPC.
resource "alicloud_vpc" "main" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# Create a vSwitch.
resource "alicloud_vswitch" "main" {
  vpc_id     = alicloud_vpc.main.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# Create an RDS instance.
resource "alicloud_db_instance" "instance" {
  engine               = "PostgreSQL"
  engine_version       = "13.0"
  instance_type        = var.instance_type
  instance_storage     = "30"
  instance_charge_type = "Postpaid"
  vswitch_id           = alicloud_vswitch.main.id
}

# Create a read-only RDS instance.
resource "alicloud_db_readonly_instance" "default" {
  master_db_instance_id = alicloud_db_instance.instance.id
  zone_id               = alicloud_db_instance.instance.zone_id
  engine_version        = alicloud_db_instance.instance.engine_version
  instance_type         = "pgro.n4.2c.1m"
  instance_storage      = "50"
  instance_name         = "${alicloud_db_instance.instance.id}ro"
  vswitch_id            = alicloud_vswitch.main.id
}

If you want to experience more examples, go to the quickstarts page and view the examples in the folder of the corresponding service.

References

  • For more information about Terraform, see What is Terraform?

  • Terraform is available as a managed service in Resource Orchestration Service (ROS). You can create Terraform templates to define ApsaraDB RDS resources, specify resource parameters, and configure dependency relationships for resources. For more information, see Create a Terraform template.

  • On this page (1, T)
  • Prerequisites
  • Resources
  • Create a read-only RDS instance
  • Clear resources
  • Complete sample code
  • Sample code
  • References
Feedback
phone Contact Us

Chat now with Alibaba Cloud Customer Service to assist you in finding the right products and services to meet your needs.

alicare alicarealicarealicare