Container Service for Kubernetes：使用Terraform建立ACK託管版叢集

使用Terraform建立ACK託管叢集（Terway）

1. 在前提條件中建立的工作目錄中建立名為main.tf的設定檔。

   說明

   main.tf用來在阿里雲上建立和配置ACK叢集資源。執行建立過程中，main.tf檔案會引用variables.tf檔案中聲明的變數。

   main.tf設定檔描述了以下的Terraform配置：

   • 建立1個新的VPC，並建立3個該VPC下的vSwitch、3個PodVSwitch。

   • 建立1個ACK託管叢集。

   • 建立1個包含2個節點的託管節點池。

   • 建立1個託管節點池。

   展開查看main.tf檔案

   provider "alicloud" {
     region = "cn-shenzhen"
     #請與variable.tf 設定檔中得地區保持一致。
   }
   
   variable "k8s_name_prefix" {   # 指定建立ACK託管叢集名稱的首碼。
     description = "The name prefix used to create managed kubernetes cluster."
     default     = "tf-ack-shenzhen"
   }
   
   resource "random_uuid" "this" {}
   # 預設資源名稱。
   locals {
     k8s_name_terway         = substr(join("-", [var.k8s_name_prefix, "terway"]), 0, 63)
     k8s_name_flannel        = substr(join("-", [var.k8s_name_prefix, "flannel"]), 0, 63)
     k8s_name_ask            = substr(join("-", [var.k8s_name_prefix, "ask"]), 0, 63)
     new_vpc_name            = "tf-vpc-172-16"
     new_vsw_name_azD        = "tf-vswitch-azD-172-16-0"
     new_vsw_name_azE        = "tf-vswitch-azE-172-16-2"
     new_vsw_name_azF        = "tf-vswitch-azF-172-16-4"
     nodepool_name           = "default-nodepool"
     managed_nodepool_name   = "managed-node-pool"
     autoscale_nodepool_name = "autoscale-node-pool"
     log_project_name        = "log-for-${local.k8s_name_terway}"
   }
   # 節點ECS執行個體配置。將查詢滿足CPU、Memory要求的ECS執行個體類型。
   data "alicloud_instance_types" "default" {
     cpu_core_count       = 8
     memory_size          = 32
     availability_zone    = var.availability_zone[0]
     kubernetes_node_role = "Worker"
   }
   # 滿足執行個體規格的AZ。
   data "alicloud_zones" "default" {
     available_instance_type = data.alicloud_instance_types.default.instance_types[0].id
   }
   # 專用網路。
   resource "alicloud_vpc" "default" {
     vpc_name   = local.new_vpc_name
     cidr_block = "172.16.0.0/12"
   }
   # Node交換器。
   resource "alicloud_vswitch" "vswitches" {
     count      = length(var.node_vswitch_ids) > 0 ? 0 : length(var.node_vswitch_cidrs)
     vpc_id     = alicloud_vpc.default.id
     cidr_block = element(var.node_vswitch_cidrs, count.index)
     zone_id    = element(var.availability_zone, count.index)
   }
   # Pod交換器。
   resource "alicloud_vswitch" "terway_vswitches" {
     count      = length(var.terway_vswitch_ids) > 0 ? 0 : length(var.terway_vswitch_cidrs)
     vpc_id     = alicloud_vpc.default.id
     cidr_block = element(var.terway_vswitch_cidrs, count.index)
     zone_id    = element(var.availability_zone, count.index)
   }
   # Kubernetes託管版。
   resource "alicloud_cs_managed_kubernetes" "default" {
     name               = local.k8s_name_terway     # Kubernetes叢集名稱。
     cluster_spec       = "ack.pro.small"           # 建立Pro版叢集。
     version            = "1.28.9-aliyun.1"
     worker_vswitch_ids = split(",", join(",", alicloud_vswitch.vswitches.*.id)) # 節點池所在的vSwitch。指定一個或多個vSwitch的ID，必須在availability_zone指定的地區中。
     pod_vswitch_ids    = split(",", join(",", alicloud_vswitch.terway_vswitches.*.id)) # Pod虛擬交換器。
     new_nat_gateway    = true               # 是否在建立Kubernetes叢集時建立新的NAT Gateway。預設為true。
     service_cidr       = "10.11.0.0/16"     # Pod網路的CIDR塊。當cluster_network_type設定為flannel，你必須設定該參數。它不能與VPC CIDR相同，並且不能與VPC中的Kubernetes叢集使用的CIDR相同，也不能在建立後進行修改。叢集中允許的最大主機數量：256。
     slb_internet_enabled = true             # 是否為API Server建立Internet負載平衡。預設為false。
     enable_rrsa        = true
     control_plane_log_components = ["apiserver", "kcm", "scheduler", "ccm"]  # 控制平面日誌。
   
     dynamic "addons" {    # 組件管理。
       for_each = var.cluster_addons
       content {
         name   = lookup(addons.value, "name", var.cluster_addons)
         config = lookup(addons.value, "config", var.cluster_addons)
       }
     }
   }
   
   resource "alicloud_cs_kubernetes_node_pool" "default" {     # 普通節點池。
     cluster_id = alicloud_cs_managed_kubernetes.default.id     # Kubernetes叢集名稱。
     node_pool_name = local.nodepool_name                       # 節點池名稱。
     vswitch_ids = split(",", join(",", alicloud_vswitch.vswitches.*.id))  # 節點池所在的vSwitch。指定一個或多個vSwitch的ID，必須在availability_zone指定的地區中。
     instance_types       = var.worker_instance_types
     instance_charge_type = "PostPaid"
     runtime_name    = "containerd"
     runtime_version = "1.6.20"
     desired_size = 2                       # 節點池的期望節點數。
     password = var.password                # SSH登入叢集節點的密碼。
     install_cloud_monitor = true           # 是否為Kubernetes的節點安裝CloudMonitor。
     system_disk_category = "cloud_efficiency"
     system_disk_size     = 100
     image_type = "AliyunLinux"
   
     data_disks {     # 節點資料盤配置。
       category = "cloud_essd"   # 節點資料盤種類。
       size = 120      # 節點資料盤大小。
     }
   }
   
   resource "alicloud_cs_kubernetes_node_pool" "managed_node_pool" {      # 託管節點池。
     cluster_id = alicloud_cs_managed_kubernetes.default.id              # Kubernetes叢集名稱。
     node_pool_name = local.managed_nodepool_name                         # 節點池名稱。
     vswitch_ids = split(",", join(",", alicloud_vswitch.vswitches.*.id)) # 節點池所在的vSwitch。指定一個或多個vSwitch的ID，必須在availability_zone指定的地區中。
     desired_size = 0         # 節點池的期望節點數。
   
     management {
       auto_repair     = true
       auto_upgrade    = true
       max_unavailable = 1
     }
   
     instance_types       = var.worker_instance_types
     instance_charge_type = "PostPaid"
     runtime_name    = "containerd"
     runtime_version = "1.6.20"
     password = var.password
     install_cloud_monitor = true
     system_disk_category = "cloud_efficiency"
     system_disk_size     = 100
     image_type = "AliyunLinux"
   
     data_disks {
       category = "cloud_essd"
       size = 120
     }
   }
   
   resource "alicloud_cs_kubernetes_node_pool" "autoscale_node_pool" {
     cluster_id = alicloud_cs_managed_kubernetes.default.id
     node_pool_name = local.autoscale_nodepool_name
     vswitch_ids = split(",", join(",", alicloud_vswitch.vswitches.*.id))
   
     scaling_config {
       min_size = 1
       max_size = 10
     }
   
     instance_types = var.worker_instance_types
     runtime_name    = "containerd"
     runtime_version = "1.6.20"
     password = var.password                # SSH登入叢集節點的密碼。
     install_cloud_monitor = true           # 是否為kubernetes的節點安裝CloudMonitor。
     system_disk_category = "cloud_efficiency"
     system_disk_size     = 100
     image_type = "AliyunLinux3"
   
     data_disks {                           # 節點資料盤配置。
       category = "cloud_essd"              # 節點資料盤種類。
       size = 120                           # 節點資料盤大小。
     }
   }
   

   關於更多的建立ACK託管叢集配置參數資訊，請參見alicloud_cs_managed_kubernetes。

2. 執行以下命令，初始化Terraform運行環境。

   terraform init

   返回資訊如下，Terraform初始化成功。

   Initializing the backend...
   
   Initializing provider plugins...
   - Checking for available provider plugins...
   - Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
   ...
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 執行以下命令，產生資源規劃。

   terraform plan

   返回資訊如下，資源規劃產生成功。

   Refreshing Terraform state in-memory prior to plan...
   The refreshed state will be used to calculate this plan, but will not be
   persisted to local or remote state storage.
   ...
   Plan: 12 to add, 0 to change, 0 to destroy.
   ...

4. 執行以下命令，建立叢集。

   terraform apply

   返回資訊如下，輸入yes，按Enter鍵，叢集建立成功。

   ...
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   ...
   alicloud_cs_managed_kubernetes.default: Creation complete after 8m26s [id=************]
   
   Apply complete! Resources: 12 added, 0 changed, 0 destroyed.