Container Service for Kubernetes：使用Terraform建立具備自動調整功能的節點池

• alicloud_instance_types：根據條件查詢符合要求的ECS執行個體類型。

• alicloud_vpc：建立Virtual Private Cloud。

• alicloud_vswitch：建立虛擬交換器（vSwitch）為VPC劃分一個或多個子網。

• alicloud_cs_managed_kubernetes：建立ACK託管版叢集。

• alicloud_cs_kubernetes_node_pool：為ACK託管叢集建立節點池。

使用Terraform建立開啟自動調整功能的節點池

未使用過alicloud_cs_kubernetes_autoscaler組件

您可以使用Terraform建立開啟自動調整功能的節點池。

1. 建立節點池的設定檔。

   為已有叢集建立開啟自動調整功能的節點池

   在已有叢集中建立開啟自動調整功能的節點池，配置樣本如下。

   provider "alicloud" {
   }
   # 為已有叢集建立開啟自動調整功能的節點池。
   resource "alicloud_cs_kubernetes_node_pool" "at1" {
     # 目的地組群ID。
     cluster_id           = ""
     name                 = "np-test"
     # 節點池內節點使用的vswitch，至少提供一個。
     vswitch_ids          = ["vsw-bp1mdigyhmilu2h4v****"]
     instance_types       = ["ecs.e3.medium"]
     password             = "Hello1234"
    
     scaling_config {
       # 最小節點數。
       min_size     = 1
       # 最大節點數。
       max_size     = 5
     }
   
   }

   建立新的具備自動調整功能的節點池叢集

   建立一個包含自動調整節點池的叢集，配置樣本如下。

   provider "alicloud" {
     region = var.region_id
   }
   
   variable "region_id" {
     type    = string
     default = "cn-shenzhen"
   }
   
   variable "cluster_spec" {
     type        = string
     description = "The cluster specifications of kubernetes cluster,which can be empty. Valid values:ack.standard : Standard managed clusters; ack.pro.small : Professional managed clusters."
     default     = "ack.pro.small"
   }
   
   variable "ack_version" {
     type        = string
     description = "Desired Kubernetes version. "
     default     = "1.28.9-aliyun.1"
   }
   
   # 指定虛擬交換器（vSwitches）的可用性區域。
   variable "availability_zone" {
     description = "The availability zones of vswitches."
     default     = ["cn-shenzhen-c", "cn-shenzhen-e", "cn-shenzhen-f"]
   }
   
   # 用於建立新vSwitches的CIDR地址塊列表。
   variable "node_vswitch_cidrs" {
     type        = list(string)
     default     = ["172.16.0.0/23", "172.16.2.0/23", "172.16.4.0/23"]
   }
   
   # 用於建立Terway使用的vSwitch的CIDR地址塊。
   variable "terway_vswitch_cidrs" {
     type        = list(string)
     default     = ["172.16.208.0/20", "172.16.224.0/20", "172.16.240.0/20"]
   }
   
   # 定義了用於啟動工作節點的ECS執行個體類型。
   variable "worker_instance_types" {
     description = "The ecs instance types used to launch worker nodes."
     default     = ["ecs.g6.2xlarge", "ecs.g6.xlarge"]
   }
   
   # 設定工作階段的密碼
   variable "password" {
     description = "The password of ECS instance."
     default     = "Test123456"
   }
   
   # 指定建立ACK託管叢集名稱的首碼。
   variable "k8s_name_prefix" {
     description = "The name prefix used to create managed kubernetes cluster."
     default     = "tf-ack-shenzhen"
   }
   
   variable "vpc_name" {
     default = "tf-vpc"
   }
   
   variable "autoscale_nodepool_name" {
     default = "autoscale-node-pool"
   }
   
   # 指定ACK叢集安裝的組件。包括Terway（網路組件）、csi-plugin（儲存群組件）、csi-provisioner（儲存群組件）、logtail-ds（日誌組件）、Nginx Ingress Controller、ack-arms-prometheus（監控組件）以及ack-node-problem-detector（節點診斷組件）。
   variable "cluster_addons" {
     type = list(object({
       name   = string
       config = string
     }))
   
     default = [
       {
         "name"   = "terway-eniip",
         "config" = "",
       },
       {
         "name"   = "logtail-ds",
         "config" = "{\"IngressDashboardEnabled\":\"true\"}",
       },
       {
         "name"   = "nginx-ingress-controller",
         "config" = "{\"IngressSlbNetworkType\":\"internet\"}",
       },
       {
         "name"   = "arms-prometheus",
         "config" = "",
       },
       {
         "name"   = "ack-node-problem-detector",
         "config" = "{\"sls_project_name\":\"\"}",
       },
       {
         "name"   = "csi-plugin",
         "config" = "",
       },
       {
         "name"   = "csi-provisioner",
         "config" = "",
       }
     ]
   }
   
   # 預設資源名稱。
   locals {
     k8s_name_terway = substr(join("-", [var.k8s_name_prefix, "terway"]), 0, 63)
   }
   
   # 節點ECS執行個體配置。將查詢滿足CPU、Memory要求的ECS執行個體類型。
   data "alicloud_instance_types" "default" {
     cpu_core_count       = 8
     memory_size          = 32
     availability_zone    = var.availability_zone[0]
     kubernetes_node_role = "Worker"
   }
   
   # 專用網路。
   resource "alicloud_vpc" "default" {
     vpc_name   = var.vpc_name
     cidr_block = "172.16.0.0/12"
   }
   
   # Node交換器。
   resource "alicloud_vswitch" "vswitches" {
     count      = length(var.node_vswitch_cidrs)
     vpc_id     = alicloud_vpc.default.id
     cidr_block = element(var.node_vswitch_cidrs, count.index)
     zone_id    = element(var.availability_zone, count.index)
   }
   
   # Pod交換器。
   resource "alicloud_vswitch" "terway_vswitches" {
     count      = length(var.terway_vswitch_cidrs)
     vpc_id     = alicloud_vpc.default.id
     cidr_block = element(var.terway_vswitch_cidrs, count.index)
     zone_id    = element(var.availability_zone, count.index)
   }
   
   # Kubernetes託管版。
   resource "alicloud_cs_managed_kubernetes" "default" {
     name                         = local.k8s_name_terway # Kubernetes叢集名稱。
     cluster_spec                 = var.cluster_spec      # 建立Pro版叢集。
     version                      = var.ack_version
     worker_vswitch_ids           = split(",", join(",", alicloud_vswitch.vswitches.*.id))        # 節點池所在的vSwitch。指定一個或多個vSwitch的ID，必須在availability_zone指定的地區中。
     pod_vswitch_ids              = split(",", join(",", alicloud_vswitch.terway_vswitches.*.id)) # Pod虛擬交換器。
     new_nat_gateway              = true                                                          # 是否在建立Kubernetes叢集時建立新的NAT Gateway。預設為true。
     service_cidr                 = "10.11.0.0/16"                                                # Pod網路的CIDR塊。當cluster_network_type設定為flannel，你必須設定該參數。它不能與VPC CIDR相同，並且不能與VPC中的Kubernetes叢集使用的CIDR相同，也不能在建立後進行修改。叢集中允許的最大主機數量：256。
     slb_internet_enabled         = true                                                          # 是否為API Server建立Internet負載平衡。預設為false。
     enable_rrsa                  = true
     control_plane_log_components = ["apiserver", "kcm", "scheduler", "ccm"] # 控制平面日誌。
     dynamic "addons" {                                                      # 組件管理。
       for_each = var.cluster_addons
       content {
         name   = lookup(addons.value, "name", var.cluster_addons)
         config = lookup(addons.value, "config", var.cluster_addons)
       }
     }
   }
   
   # 建立自動調整節點池，節點池最多可以擴充到 10 個節點，最少保持 1 個節點。
   resource "alicloud_cs_kubernetes_node_pool" "autoscale_node_pool" {
     cluster_id     = alicloud_cs_managed_kubernetes.default.id
     node_pool_name = var.autoscale_nodepool_name
     vswitch_ids    = split(",", join(",", alicloud_vswitch.vswitches.*.id))
   
     scaling_config {
       min_size = 1
       max_size = 10
     }
   
     instance_types        = var.worker_instance_types
     runtime_name          = "containerd"
     runtime_version       = "1.6.20"
     password              = var.password # SSH登入叢集節點的密碼。
     install_cloud_monitor = true         # 是否為kubernetes的節點安裝CloudMonitor。
     system_disk_category  = "cloud_efficiency"
     system_disk_size      = 100
     image_type            = "AliyunLinux3"
   
     data_disks {              # 節點資料盤配置。
       category = "cloud_essd" # 節點資料盤種類。
       size     = 120          # 節點資料盤大小。
     }
   }

2. 執行如下命令，初始化Terraform運行環境。

   terraform init

   返回資訊如下，Terraform初始化成功。

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. 執行terraform apply命令完成建立。

4. 驗證結果。

   完成建立節點池後，在節點池列表中可以看到建立的節點池，該節點池名稱下會標註已開啟自動調整。