可以在本地或ECS上安装Cassandra，通过cqlsh工具访问云数据库Cassandra。
下载和安装Cassandra
在Apache Cassandra官方网站下载最新版本的Cassandra然后解压，即可完成安装。
$ wget http://mirror.bit.edu.cn/apache/cassandra/3.11.4/apache-cassandra-3.11.4-bin.tar.gz
$ tar -zxf apache-cassandra-3.11.4-bin.tar.gz
$ cd apache-cassandra-3.11.4 使用cqlsh连接云数据Cassandra
在云数据Cassandra的控制台查看云数据Cassandra的地址和端口，然后在本地或ECS上使用cqlsh连接，命令如下：
bin/cqlsh $host $port -u $username -p $password 如果您需要经常连接到特定节点，您可以将节点的地址和端口信息保存到环境变量$CQLSH_HOST和$CQLSH_PORT中。更多关于cqlsh命令支持的参数可以使用bin/cqlsh -help。
基本的cqlsh命令
cqlsh支持多种操作Cassandra的基本命令，您可以使用HELP或?命令查看所有支持的命令：
cqlsh> HELP
Documented shell commands:
===========================
CAPTURE CLS COPY DESCRIBE EXPAND LOGIN SERIAL SOURCE UNICODE
CLEAR CONSISTENCY DESC EXIT HELP PAGING SHOW TRACING
CQL help topics:
================
AGGREGATES CREATE_KEYSPACE DROP_TRIGGER TEXT
ALTER_KEYSPACE CREATE_MATERIALIZED_VIEW DROP_TYPE TIME
ALTER_MATERIALIZED_VIEW CREATE_ROLE DROP_USER TIMESTAMP
ALTER_TABLE CREATE_TABLE FUNCTIONS TRUNCATE
ALTER_TYPE CREATE_TRIGGER GRANT TYPES
ALTER_USER CREATE_TYPE INSERT UPDATE
APPLY CREATE_USER INSERT_JSON USE
ASCII DATE INT UUID
BATCH DELETE JSON
BEGIN DROP_AGGREGATE KEYWORDS
BLOB DROP_COLUMNFAMILY LIST_PERMISSIONS
BOOLEAN DROP_FUNCTION LIST_ROLES
COUNTER DROP_INDEX LIST_USERS
CREATE_AGGREGATE DROP_KEYSPACE PERMISSIONS
CREATE_COLUMNFAMILY DROP_MATERIALIZED_VIEW REVOKE
CREATE_FUNCTION DROP_ROLE SELECT
CREATE_INDEX DROP_TABLE SELECT_JSON 如果需要查看特定命令的帮助，可以使用HELP。需要注意的是，很多cqlsh命令并不接收相关的参数，当您使用这些命令时，其输出为当前的设置，比如CONSISTENCY，EXPAND和PAGING命令，如下：
cqlsh> CONSISTENCY
Current consistency level is ONE.
cqlsh> EXPAND
Expanded output is currently disabled. Use EXPAND ON to enable.
cqlsh> PAGING
Query paging is currently enabled. Use PAGING OFF to disable
Page size: 100 在cqlsh里面查看环境变量
您可以使用DESCRIBE命令，来查看一些集群的一些环境变量的值，例如：
cqlsh> DESCRIBE CLUSTER;
Cluster: Test Cluster
Partitioner: Murmur3Partitioner DESCRIBE CLUSTER显示了集群的名字以及采用的Partitioner，Cassandra 1.2版本开始默认为Murmur3Partitioner，其他可选的Partitioner有RandomPartitioner（Cassandra 1.2 版本之前默认的Partitioner）、OrderPreservingPartitioner以及ByteOrderedPartitioner等。
如果您需要查看集群里面可用的Keyspaces，可以使用下面命令：
cqlsh> DESCRIBE KEYSPACES; 上面命令将system_traces、system_schema、system_auth、system system_distributed等系统自带的Keyspaces都显示出来了，如果您创建了Keyspaces，也会在这里显示。
可以使用下面命令查看cqlsh、Cassandra以及protocol的版本：
cqlsh> SHOW VERSION;
[cqlsh 5.0.1 | Cassandra 3.11.4 | CQL spec 3.4.4 | Native protocol v4] 通过cqlsh创建Keyspace
Cassandra中的Keyspace和关系型数据库中的database概念比较类似，一个Keyspace可以包含一个或多个tables或column families。当您启动cqlsh时没有指定Keyspace，那么命令提示符为cqlsh>，您可以使用CREATE KEYSPACE命令来创建Keyspace，具体如下：
cqlsh> CREATE KEYSPACE test_keyspace WITH replication = {'class': 'SimpleStrategy', 'replication_factor': 1};
cqlsh> 上面命令创建了名为test_keyspace的Keyspace；并且采用SimpleStrategy进行副本复制。由于当前的测试集群只有单个节点，所以设置副本因子（replication factor）为1。如果是生产环境，请勿将副本因子设置为1，建议将副本因子设置为3。
创建完Keyspace之后，您可以使用DESCRIBE KEYSPACE命令来查看这个Keyspace：
cqlsh> DESCRIBE KEYSPACE test_keyspace;
CREATE KEYSPACE test_keyspace WITH replication = {'class': 'SimpleStrategy', 'replication_factor': '1'} AND durable_writes = true; 现在您可以使用USE命令来切换到这个Keyspace：
cqlsh> USE test_keyspace;
cqlsh:test_keyspace> 通过cqlsh创建表
创建表：
cqlsh> use test_keyspace;
cqlsh:test_keyspace> CREATE TABLE test_user (first_name text , last_name text, PRIMARY KEY (first_name));
上述命令表示在test_keyspace下面创建了一张名为test_user的表。其中包含了first_name和last_name两个字段，类型都是text，并且first_name是这张表的PRIMARY KEY。当然，您也可以通过下述命令在test_keyspace里面建表：
cqlsh> CREATE TABLE test_keyspace.test_user(first_name text , last_name text, PRIMARY KEY (first_name));
查看建表语句：
cqlsh:test_keyspace> DESCRIBE TABLE test_user;
CREATE TABLE test_keyspace.test_user (
first_name text PRIMARY KEY,
last_name text
) WITH bloom_filter_fp_chance = 0.01
AND caching = {'keys': 'ALL', 'rows_per_partition': 'NONE'}
AND comment = ''
AND compaction = {'class': 'org.apache.cassandra.db.compaction.SizeTieredCompactionStrategy', 'max_threshold': '32', 'min_threshold': '4'}
AND compression = {'chunk_length_in_kb': '64', 'class': 'org.apache.cassandra.io.compress.LZ4Compressor'}
AND crc_check_chance = 1.0
AND dclocal_read_repair_chance = 0.1
AND default_time_to_live = 0
AND gc_grace_seconds = 864000
AND max_index_interval = 2048
AND memtable_flush_period_in_ms = 0
AND min_index_interval = 128
AND read_repair_chance = 0.0
AND speculative_retry = '99PERCENTILE';
cqlsh:test_keyspace> DESCRIBE TABLE命令会将建表语句以格式化的形式显示出来，除了您制定的设置，还包含了许多默认的设置。
通过cqlsh读写数据
往表里面插入一些数据：
cqlsh:test_keyspace> INSERT INTO test_user (first_name, last_name) VALUES ('test', 'Hadoop');
cqlsh:test_keyspace> INSERT INTO test_user (first_name, last_name) VALUES ('Zhang', 'San');
cqlsh:test_keyspace> INSERT INTO test_user (first_name) VALUES ('Li'); 上述语句表示往test_user表中插入三条数据，其中最后一条数据只指定了Key，last_name没有值。
您可以使用SELECT COUNT语句查看数据是否插入成功。
cqlsh:test_keyspace> SELECT COUNT(*) FROM test_user;
count
-------
3
(1 rows)
Warnings :
Aggregation query used without partition key 通过命令的输出查看已成功插入数据。您还可以使用下述命令查询这条数据：
cqlsh:test_keyspace> SELECT * FROM test_user;
first_name | last_name
------------+-----------
test | Hadoop
Wang | null
Zhang | San
(3 rows)
cqlsh:test_keyspace> SELECT * FROM test_user WHERE first_name='test';
first_name | last_name
------------+-----------
test | Hadoop
(1 rows) 可以看出，由于first_name为Wang对应的last_name没有数据，这里直接显示null。在Cassandra中，null代表对应的列没有数据，在底层存储是不占用空间的，而在常见的关系型数据库里面是占一定空间的。
删除列或行
使用DELETE命令删除一些列。例如，删除last_name列：
cqlsh:test_keyspace> DELETE last_name FROM test_user WHERE first_name='test';
cqlsh:test_keyspace> SELECT * FROM test_user WHERE first_name='test';
first_name | last_name
------------+-----------
test | null
(1 rows) 可以看出last_name列已经成功被删除。
使用DELETE命令删除一整行的数据：
cqlsh:test_keyspace> DELETE FROM test_user WHERE first_name='test';
cqlsh:test_keyspace> SELECT * FROM test_user WHERE first_name='test';
first_name | last_name
------------+-----------
(0 rows)
cqlsh:test_keyspace> 可以看到Key为test的数据已经成功被删除。
insert/update相当于upsert，如果您插入数据对应的Key在Cassandra已经存在了，这时候Cassandra不会在原来数据位置上修改数据，而是会新写入一份数据，旧的数据会被Cassandra删除。
cqlsh:test_keyspace> INSERT INTO test_user (first_name, last_name) VALUES ('Wang', 'Shi');
cqlsh:test_keyspace> SELECT * FROM test_user;
first_name | last_name
------------+-----------
Wang | Shi
Zhang | San
(2 rows) 可以看出，Key为Wang的数据对应的last_name已经有值了。
如果使用UPDATE命令更新不存在的数据，Cassandra会插入新的数据，例如：
cqlsh:test_keyspace> SELECT * FROM test_user;
first_name | last_name
------------+-----------
Wang | Shi
Zhang | San
(2 rows)
cqlsh:test_keyspace> UPDATE test_user SET last_name = 'Si' WHERE first_name = 'Li';
cqlsh:test_keyspace> SELECT * FROM test_user;
first_name | last_name
------------+-----------
Wang | Shi
Zhang | San
Li | Si
(3 rows)
cqlsh:test_keyspace> 可以看出，Key为Li的数据被插入到表中了，而更新之前该数据不存在。
清空或删除表
如果您需要清空一张表，您可以使用TRUNCATE命令或DROP TABLE命令，例如：
cqlsh:test_keyspace> TRUNCATE test_user;
cqlsh:test_keyspace> DROP TABLE test_user;