通過Terraform配置Logtail採集 - Simple Log Service

Terraform是一種開源工具，用於安全高效地預覽、配置和管理雲基礎架構和資源。本文介紹如何通過Terraform配置Logtail採集。

說明

本教程所含範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

前提條件

已開通Log Service。具體操作，請參見資源管理概述。

為了降低資訊安全風險，建議使用最小許可權的RAM使用者完成此教程的操作。請參見建立RAM使用者與為RAM使用者授權，完成此教程要求的權限的權限原則如下：

{
  "Version": "1",
  "Statement": [
    {
      "Effect": "Allow",
      "Action": [
        "log:GetProject",
        "log:ListProject",
        "log:CreateProject",
        "log:DeleteProject",
        "log:UpdateProject",
        "log:GetAppliedMachineGroups",
        "log:GetMachineGroup",
        "log:ListMachineGroup",
        "log:CreateMachineGroup",
        "log:GetLogStore",
        "log:GetLogStoreLogs",
        "log:GetLogStoreMeteringMode",
        "log:ListLogStores",
        "log:CreateLogStore",
        "log:PostLogStoreLogs",
        "log:UpdateLogStore",
        "log:GetLogtailPipelineConfig",
        "log:UpdateLogtailPipelineConfig",
        "log:ListTagResources",
        "log:ListShards",
        "log:ListSavedSearch",
        "log:GetIndex",
        "log:ListDashboard",
        "log:ListConfig",
        "log:CreateConfig",
        "log:GetConfig",
        "log:ApplyConfigToGroup",
        "log:DeleteConfig",
        "log:DeleteMachineGroup",
        "log:GetProjectPolicy",
        "log:DeleteLogStore"
      ],
      "Resource": "*"
    }
  ]
}

準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。
- Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。
- 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

說明

本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行釋放或退訂。

使用的資源

alicloud_log_project：專案（Project）。
alicloud_log_machine_group：機器組。
alicloud_log_store：日誌庫（Logstore）。
alicloud_logtail_config：Logtail配置。
alicloud_logtail_attachment：應用Logtail採集配置到機器組。

步驟一：建立專案

建立一個工作目錄，並在該工作目錄中建立名為main.tf的設定檔。將代碼複製到main.tf中。

variable "region" {
  default = "cn-hangzhou"
}

variable "identify_list" {
  type        = list(string)
  description = "機器組包含的機器IP"
  default     = ["10.0.0.1", "10.0.0.2"]
}

provider "alicloud" {
  region = var.region
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

# 專案（Project）
resource "alicloud_log_project" "example" {
  project_name = "project-name-${random_integer.default.result}"
  description  = "tf actiontrail example"
}

執行如下命令，初始化Terraform運行環境。

terraform init

返回資訊如下，則Terraform初始化成功。

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

執行如下命令，開始執行代碼。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示代碼執行成功。

You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes


Apply complete! Resources: 2 added, 0 changed, 0 destroyed.

驗證結果。
執行terraform show命令
您可以在工作目錄中，使用以下命令查詢Terraform已建立資源的詳細資料：
```
terraform show
```
登入控制台查看
登入Log Service控制台，查看已建立的Project。

步驟二：建立機器組與日誌庫

在main.tf檔案中增加如下代碼。

# 機器組
resource "alicloud_log_machine_group" "example" {
  project     = alicloud_log_project.example.project_name
  name          = "terraform-example-${random_integer.default.result}"
  identify_type = "ip"
  topic         = "terraform"
  identify_list = var.identify_list
}

# 日誌庫（Logstore）
resource "alicloud_log_store" "example" {
  project_name = alicloud_log_project.example.project_name
  logstore_name = "logstore_example_${random_integer.default.result}"
  retention_period = 3
}

建立執行計畫，並預覽變更。
```
terraform plan
```
執行如下命令，開始執行代碼。
```
terraform apply
```
在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示代碼執行成功。
```
Apply complete! Resources: 2 added, 0 changed, 0 destroyed.
```
驗證結果。
執行terraform show命令
您可以在工作目錄中，使用以下命令查詢Terraform已建立資源的詳細資料：
```
terraform show
```
登入控制台查看
1. 登入Log Service控制台，單擊Project列表的專案名稱，單擊日誌儲存，查看已建立的日誌庫。
2. 單擊資源 > 機器組，查看已建立的機器組。

步驟三：配置Logtail採集

在main.tf檔案中增加如下代碼。

# Logtail採集
resource "alicloud_logtail_config" "example" {
  project     = alicloud_log_project.example.project_name
  logstore    = alicloud_log_store.example.logstore_name
  name        = "config-sample-${random_integer.default.result}"
  input_type  = "file"
  output_type = "LogService"
  input_detail = jsonencode(
  	{
		"logPath": "/logPath",
		"filePattern": "access.log",
		"logType": "json_log",
		"topicFormat": "default",
		"discardUnmatch": false,
		"enableRawLog": true,
		"fileEncoding": "gbk",
		"maxDepth": 10
	}
  )
}

# 應用Logtail採集配置到機器組
resource "alicloud_logtail_attachment" "example" {
  project     = alicloud_log_project.example.project_name
  logtail_config_name = alicloud_logtail_config.example.name
  machine_group_name  = alicloud_log_machine_group.example.name
}

建立執行計畫，並預覽變更。
```
terraform plan
```
執行如下命令，開始執行代碼。
```
terraform apply
```
在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示代碼執行成功。
```
Apply complete! Resources: 2 added, 0 changed, 0 destroyed.
```
驗證結果。
執行terraform show命令
您可以在工作目錄中，使用以下命令查詢Terraform已建立資源的詳細資料：
```
terraform show
```
登入控制台查看
1. 登入Log Service控制台，單擊Project列表的專案名稱，單擊日誌儲存，再單擊Logtail配置，查看Logtail配置。
2. 單擊Logtail配置的配置名稱，進入機器組管理頁簽，查看已配置的機器組。

清理資源

當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

terraform destroy

完整樣本

說明

本教程所含範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

範例程式碼

variable "region" {
  default = "cn-hangzhou"
}

variable "identify_list" {
  type        = list(string)
  description = "機器組包含的機器IP"
  default     = ["10.0.0.1", "10.0.0.2"]
}

provider "alicloud" {
  region = var.region
}

resource "random_integer" "default" {
  min = 10000
  max = 99999
}

# 專案（Project）
resource "alicloud_log_project" "example" {
  project_name = "project-name-${random_integer.default.result}"
  description  = "tf actiontrail example"
}

# 機器組
resource "alicloud_log_machine_group" "example" {
  project     = alicloud_log_project.example.project_name
  name          = "terraform-example-${random_integer.default.result}"
  identify_type = "ip"
  topic         = "terraform"
  identify_list = var.identify_list
}

# 日誌庫（Logstore）
resource "alicloud_log_store" "example" {
  project_name = alicloud_log_project.example.project_name
  logstore_name = "logstore_example_${random_integer.default.result}"
  retention_period = 3
}

# Logtail採集
resource "alicloud_logtail_config" "example" {
  project     = alicloud_log_project.example.project_name
  logstore    = alicloud_log_store.example.logstore_name
  name        = "config-sample-${random_integer.default.result}"
  input_type  = "file"
  output_type = "LogService"
  input_detail = jsonencode(
  	{
		"logPath": "/logPath",
		"filePattern": "access.log",
		"logType": "json_log",
		"topicFormat": "default",
		"discardUnmatch": false,
		"enableRawLog": true,
		"fileEncoding": "gbk",
		"maxDepth": 10
	}
  )
}

# 應用Logtail採集配置到機器組
resource "alicloud_logtail_attachment" "example" {
  project     = alicloud_log_project.example.project_name
  logtail_config_name = alicloud_logtail_config.example.name
  machine_group_name  = alicloud_log_machine_group.example.name
}

如果您想體驗更多完整樣本，請前往更多完整樣本中對應產品的檔案夾查看。

Simple Log Service：通過Terraform配置Logtail採集

前提條件

使用的資源

步驟一：建立專案

執行terraform show命令

登入控制台查看

步驟二：建立機器組與日誌庫

執行terraform show命令

登入控制台查看

步驟三：配置Logtail採集

執行terraform show命令

登入控制台查看

清理資源

完整樣本

範例程式碼

相關文檔