如何通過Terraform建立ApsaraDB for MongoDB執行個體 - ApsaraDB for MongoDB

本文為您示範如何通過Terraform建立ApsaraDB for MongoDB執行個體。

說明

當前範例程式碼支援一鍵運行，您可以直接運行代碼。

如果您還不瞭解Terraform，請參見Terraform產品介紹。關於支援的MongoDB資源類型，請參見整合概覽或直接尋找Terraform文檔。

資源架構

在指定地區建立一個VPC網路和一台交換器，然後建立一個MongoDB複本集執行個體。

前提條件

由於阿里雲帳號（主帳號）具有資源的所有許可權，一旦發生泄露將面臨重大風險。建議您使用RAM使用者，並為該RAM使用者建立AccessKey，具體操作方式，請參見建立RAM使用者和建立AccessKey。

為RAM使用者授予AliyunMongoDBFullAccess（管理雲資料庫服務（MongoDB））和AliyunVPCFullAccess（管理Virtual Private Cloud）許可權。授權樣本如下，如何授權，請參見為RAM使用者授權。

{
    "Version": "1",
    "Statement": [
        {
            "Action": "dds:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": [
                "vpc:DescribeVpcs",
                "vpc:DescribeVSwitches",
                "vpc:CreateVpc",
                "vpc:DeleteVpc",
                "vpc:ModifyVpcAttribute",
                "vpc:CreateVSwitch",
                "vpc:DeleteVSwitch",
                "vpc:ModifyVSwitchAttribute"
            ],
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "hdm:*",
            "Resource": "acs:dds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "dms:LoginDatabase",
            "Resource": "acs:dds:*:*:*",
            "Effect": "Allow"
        },
        {
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Effect": "Allow",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": "mongodb.aliyuncs.com"
                }
            }
        }
    ]
}

準備Terraform運行環境，您可以選擇以下任一方式來使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里雲提供了Terraform的線上運行環境，您無需安裝Terraform，登入後即可線上使用和體驗Terraform。適用於零成本、快速、便捷地體驗和調試Terraform的情境。
- Cloud Shell：阿里雲Cloud Shell中預裝了Terraform的組件，並已配置好身份憑證，您可直接在Cloud Shell中運行Terraform的命令。適用於低成本、快速、便捷地訪問和使用Terraform的情境。
- 在本地安裝和配置Terraform：適用於網路連接較差或需要自訂開發環境的情境。

重要

請確保Terraform版本不低於v0.12.28。如需檢查現有版本，請運行terraform --version命令。

說明

本教程樣本包含的部分資源會產生一定費用，請在不需要時及時進行退訂。

使用的資源

alicloud_mongodb_instance：提供一個 MongoDB 執行個體資源，支援複本集執行個體。
alicloud_mongodb_sharding_instance：建立一個支援複本集執行個體的 MongoDB 分區執行個體資源。

使用Terraform建立ApsaraDB for MongoDB執行個體

建立一個工作目錄，並且在工作目錄中建立以下名為main.tf的設定檔。main.tf是Terraform主檔案，定義了將要部署的資源。

單節點

variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
# 聲明變數名: name
variable "name" {
  default = "terraform-example-1125"
}
variable "engine_version" {
  default = "7.0"
}
variable "db_instance_class" {
  default = "mdb.shard.2x.xlarge.d"
}
# 查詢可用性區域資訊: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
}
# 聲明本地值, zone_id 取 alicloud_mongodb_zones 中的最後一個可用性區域
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}
# 建立 alicloud_vpc 資源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地區建立 alicloud_vpc 資源下的 alicloud_vswitch 資源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch資訊建立單節點資源
resource "alicloud_mongodb_instance" "singleNode" {
  # （必填）資料庫版本。
  engine_version      = var.engine_version
  # （必填）執行個體規格。
  db_instance_class   = var.db_instance_class
  # （必填，整型）使用者定義的資料庫執行個體儲存空間。單位：GB。
  db_instance_storage = 20
  # 執行個體的網路類型
  network_type        = "VPC"
  # （可選，需強制建立）在一個 VPC 中啟動資料庫執行個體的虛擬交換器 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # （可選，需強制建立）啟動資料庫執行個體的可用性區域。
  zone_id             = local.zone_id
  # 執行個體名稱  
  name                = var.name
  # （可選，自 v1.199.0 起可用）執行個體的儲存類型。
  # storage_type        = "cloud_auto"
  # （可選）要分配給資源的標籤映射。
  # tags = {
  #   Created = "TF"
  #   For     = "example"
  #   }
  # （可選，列表）允許訪問執行個體所有資料庫的 IP 位址列表。
  # security_ip_list    = [
        # "10.168.1.12",
        # "100.69.7.112"
  #   ]
}

關於alicloud_mongodb_instance資源類型的配置資訊，請參見資源詳情。

複本集

variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
# 聲明變數名: name
variable "name" {
  default = "terraform-example-1125"
}
variable "engine_version" {
  default = "7.0"
}
variable "db_instance_class" {
  default = "mdb.shard.2x.xlarge.d"
}

# 查詢可用性區域資訊: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
}

# 聲明本地值, zone_id 取 alicloud_mongodb_zones 中的最後一個可用性區域
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}

# 建立 alicloud_vpc 資源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地區建立 alicloud_vpc 資源下的 alicloud_vswitch 資源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch資訊棄置站台集資源
resource "alicloud_mongodb_instance" "default" {
  engine_version      = var.engine_version
  db_instance_class   = var.db_instance_class
  db_instance_storage = 20
  network_type        = "VPC"
  vswitch_id          = alicloud_vswitch.default.id
  vpc_id              = alicloud_vpc.vpc1.id
  security_ip_list    = ["10.168.1.12", "100.69.7.112"]
  name                = var.name
  tags = {
    Created = "TF"
    For     = "example"
  }
}

關於alicloud_mongodb_instance資源類型的配置資訊，請參見資源詳情。

分區叢集

variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}

# 聲明變數名: name
variable "name" {
  default = "terraform-example-1125"
}

# 查詢可用性區域資訊: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
  
}

# 聲明本地值, zone_id 取 alicloud_mongodb_zones 中的最後一個可用性區域
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}

# 建立 alicloud_vpc 資源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地區建立 alicloud_vpc 資源下的 alicloud_vswitch 資源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch資訊建立分區叢集資源
resource "alicloud_mongodb_sharding_instance" "default" {
  # (必填) 資料庫版本
  engine_version      = "7.0"
  # (可選，ForceNew) 啟動 DB 執行個體的虛擬交換器 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # 執行個體的網路類型
  network_type        = "VPC"
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # 執行個體名稱
  name                = var.name
  # 可選地區
  zone_id = local.zone_id
  # 執行個體的 Mongo 節點。可購買的 mongo 節點數範圍為 [2, 32]，見下方的 mongo_list。
  mongo_list {
    # (必填) mongo 節點的執行個體類型
    node_class = "mdb.shard.2x.xlarge.d"
  }
  mongo_list {
    node_class = "mdb.shard.2x.xlarge.d"
  }
  # (必填，集合) 執行個體的分區節點。可購買的 shard 節點數範圍為 [2, 32]，見下方的 shard_list。
  shard_list {
    # (必填) 分區節點的執行個體類型
    node_class   = "mdb.shard.2x.xlarge.d"
    #  (必填，Int) 分區節點的儲存空間。
    node_storage = "20"
  }
  shard_list {
    node_class        = "mdb.shard.2x.xlarge.d"
    node_storage      = "20"
    # 分區節點中唯讀節點的數量。預設值：0。有有效值：0 到 5。
    readonly_replicas = "1"
  }
  config_server_list {
    # 設定管理員節點的執行個體類型。有效值：mdb.shard.2x.xlarge.d，dds.cs.mid。
    node_class ="mdb.shard.2x.xlarge.d"
    # 設定管理員節點的儲存空間。
    node_storage = "20"
  }
  # 
  tags = {
    Created = "TF"
    For     = "Example"
  }
}

關於alicloud_mongodb_sharding_instance資源類型的配置資訊，請參見資源詳情。

執行以下命令，初始化Terraform運行環境。

terraform init

返回如下資訊，表示Terraform初始化成功。

Initializing the backend...

Initializing provider plugins...
- Finding latest version of hashicorp/alicloud...
- Installing hashicorp/alicloud v1.234.0...
- Installed hashicorp/alicloud v1.234.0 (signed by HashiCorp)

Terraform has created a lock file .terraform.lock.hcl to record the provider
selections it made above. Include this file in your version control repository
so that Terraform can guarantee to make the same selections by default when
you run "terraform init" in the future.

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

建立執行計畫，並預覽變更。
```
terraform plan
```

執行以下命令，建立ApsaraDB for MongoDB執行個體。

terraform apply

在執行過程中，根據提示輸入yes並按下Enter鍵，等待命令執行完成，若出現以下資訊，則表示建立ApsaraDB for MongoDB執行個體成功。

Plan: 3 to add, 0 to change, 0 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

alicloud_vpc.vpc1: Creating...
alicloud_vpc.vpc1: Creation complete after 6s [id=vpc-f8zov2h1snsl2bm9qz***]
alicloud_vswitch.default: Creating...
alicloud_vswitch.default: Creation complete after 3s [id=vsw-f8zswqowidqw16ypc2***]
alicloud_mongodb_instance.singleNode: Creating...
alicloud_mongodb_instance.singleNode: Still creating... [10s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [20s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [30s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [40s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [50s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [1m0s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [1m10s elapsed]

...

alicloud_mongodb_instance.singleNode: Still creating... [14m11s elapsed]
alicloud_mongodb_instance.singleNode: Still creating... [14m21s elapsed]
alicloud_mongodb_instance.singleNode: Creation complete after 14m29s [id=dds-f8z3a787aea1c***]

Apply complete! Resources: 3 added, 0 changed, 0 destroyed.

驗證結果。
執行terraform show命令
您可以使用以下命令查詢Terraform已建立的資來源詳細資料：
```
terraform show
```
登入雲資料庫Mongo DB控制台
建立完成後，您可以通過OpenAPI、SDK或者登入雲資料庫Mongo DB控制台，檢查操作是否正確完成。

清理資源

當您不再需要上述通過Terraform建立或管理的資源時，請運行以下命令以釋放資源。關於terraform destroy的更多資訊，請參見常用命令。

terraform destroy

完整樣本

說明

當前範例程式碼支援一鍵運行，您可以直接運行代碼。一鍵運行

範例程式碼

variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
# 聲明變數名: name
variable "name" {
  default = "terraform-example-1125"
}
variable "engine_version" {
  default = "7.0"
}
variable "db_instance_class" {
  default = "mdb.shard.2x.xlarge.d"
}
# 查詢可用性區域資訊: alicloud_mongodb_zones
data "alicloud_mongodb_zones" "default" {
}
# 聲明本地值, zone_id 取 alicloud_mongodb_zones 中的最後一個可用性區域
locals {
  index   = length(data.alicloud_mongodb_zones.default.zones) - 1
  zone_id = data.alicloud_mongodb_zones.default.zones[local.index].id
}
# 建立 alicloud_vpc 資源
resource "alicloud_vpc" "vpc1" {
  vpc_name   = var.name
  cidr_block = "172.16.0.0/12"
}

# 在 local.zone_id 地區建立 alicloud_vpc 資源下的 alicloud_vswitch 資源
resource "alicloud_vswitch" "default" {
  vswitch_name = var.name
  cidr_block   = "172.16.20.0/24"
  vpc_id       = alicloud_vpc.vpc1.id
  zone_id      = local.zone_id
}

# 使用上述vpc、vswitch資訊建立單節點資源
resource "alicloud_mongodb_instance" "singleNode" {
  # （必填）資料庫版本。
  engine_version      = var.engine_version
  # （必填）執行個體規格。
  db_instance_class   = var.db_instance_class
  # （必填，整型）使用者定義的資料庫執行個體儲存空間。單位：GB。
  db_instance_storage = 20
  # 執行個體的網路類型
  network_type        = "VPC"
  # （可選，需強制建立）在一個 VPC 中啟動資料庫執行個體的虛擬交換器 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # （可選，需強制建立）啟動資料庫執行個體的可用性區域。
  zone_id             = local.zone_id
  # 執行個體名稱  
  name                = var.name
  # （可選）要分配給資源的標籤映射。
  tags = {
    Created = "TF"
    For     = "example"
    }
  # （可選，列表）允許訪問執行個體所有資料庫的 IP 位址列表。
  security_ip_list    = [
         "10.168.1.12",
         "100.69.7.112"
     ]
  # （可選，自 v1.199.0 起可用）執行個體的儲存類型。
  # storage_type        = "cloud_auto"   
}
# 使用上述vpc、vswitch資訊建立分區叢集資源
resource "alicloud_mongodb_sharding_instance" "default" {
  # (必填) 資料庫版本
  engine_version      = "7.0"
  # (可選，ForceNew) 啟動 DB 執行個體的虛擬交換器 ID。
  vswitch_id          = alicloud_vswitch.default.id
  # 執行個體的網路類型
  network_type        = "VPC"
  # vpc_id
  vpc_id              = alicloud_vpc.vpc1.id
  # 執行個體名稱
  name                = var.name
  # 可選地區
  zone_id = local.zone_id
  # 執行個體的 Mongo 節點。可購買的 mongo 節點數範圍為 [2, 32]，見下方的 mongo_list。
  mongo_list {
    # (必填) mongo 節點的執行個體類型
    node_class = "mdb.shard.2x.xlarge.d"
  }
  mongo_list {
    node_class = "mdb.shard.2x.xlarge.d"
  }
  # (必填，集合) 執行個體的分區節點。可購買的 shard 節點數範圍為 [2, 32]，見下方的 shard_list。
  shard_list {
    # (必填) 分區節點的執行個體類型
    node_class   = "mdb.shard.2x.xlarge.d"
    #  (必填，Int) 分區節點的儲存空間。
    node_storage = "20"
  }
  shard_list {
    node_class        = "mdb.shard.2x.xlarge.d"
    node_storage      = "20"
    # 分區節點中唯讀節點的數量。預設值：0。有有效值：0 到 5。
    readonly_replicas = "1"
  }
  config_server_list {
    # 設定管理員節點的執行個體類型。有效值：mdb.shard.2x.xlarge.d，dds.cs.mid。
    node_class ="mdb.shard.2x.xlarge.d"
    # 設定管理員節點的儲存空間。
    node_storage = "20"
  }
  # 
  tags = {
    Created = "TF"
    For     = "Example"
  }
}

如果您想體驗更多完整樣本，請前往更多完整樣本中對應產品的檔案夾查看。