Virtual Private Cloud:VPC peering connections

Create a peering connection

1. Call CreateVpcPeerConnection to create a VPC peering connection.

2. If the two VPCs belong to different accounts, the owner of the accepter account must call AcceptVpcPeerConnection to accept the VPC peering connection.

   The accepter can call RejectVpcPeerConnection to reject the VPC peering connection.

3. The owners of both VPCs must call GetVpcPeerConnectionAttribute to query the CIDR blocks of the two VPCs.

4. The owners of both VPCs must call CreateRouteEntry to create routes that point to the peering connection.

Modify a cross-region peering connection

Call ModifyVpcPeerConnection to modify the bandwidth or link type of a cross-region VPC peering connection.

Delete a peering connection

• Call DeleteRouteEntry to delete the routes that point to the peering connection.

• Call DeleteVpcPeerConnection to delete the VPC peering connection.

Reachability Analyzer

Call the following API operations in sequence to use Reachability Analyzer to check connectivity.

1. CreateNetworkPath

2. CreateNetworkReachableAnalysis

3. GetNetworkReachableAnalysis

Same-account peering connection

Resources: alicloud_vpc_peer_connection, alicloud_route_entry

Data Sources: alicloud_account

# The account to which the VPC belongs
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "ap-southeast-1" # The region where the requester VPC is located.
}

provider "alicloud" {
  alias  = "accepting"
  region = "eu-west-1" # The region of the accepter VPC. It can be the same as the region of the requester VPC. Configure this parameter based on the region of the accepter VPC.
}

# Requester VPC ID
variable "local_vpc_id" {
  default = "vpc-t4ns******"
}

# Accepter VPC ID
variable "accepting_vpc_id" {
  default = "vpc-d7ot******"
}

# Create a VPC peering connection
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # Requester VPC ID
  accepting_ali_uid    = data.alicloud_account.default.id # Accepter account ID   
  accepting_region_id  = "eu-west-1"                     # The region where the accepter VPC is located
  accepting_vpc_id     = var.accepting_vpc_id             # Accepter VPC ID
  bandwidth            = 1024                             # The bandwidth in Mbit/s. You can configure this parameter only when the requester region and the accepter region are different.
  link_type            = "Gold"                           # The link type. You can configure this parameter only when the requester region and the accepter region are different.
}

# Configure a route for the requester VPC
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-t4nl******"            # The route table bound to the vSwitch where the requester instance is located
  destination_cidrblock = "172.16.0.0/12"             # The CIDR block of the accepter VPC
  nexthop_type          = "VpcPeer"                   # The next hop is a VPC peering connection
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Configure a route for the accepter VPC
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-d7od******"            # The route table bound to the vSwitch where the accepter instance is located
  destination_cidrblock = "10.0.0.0/8"                # The CIDR block of the requester VPC
  nexthop_type          = "VpcPeer"                   # The next hop is a VPC peering connection
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

Cross-account peering connection

Resources: alicloud_vpc_peer_connection, alicloud_vpc_peer_connection_accepter, alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "ap-southeast-1" # The region of the requester VPC 
}

# The region of the accepter VPC. It can be the same as the region of the requester VPC. You need to configure it based on the region of the accepter VPC.
variable "accepting_region" {
  default = "eu-west-1"
}

# The accepter account
variable "accepting_uid" {
  default = "1234******"
}

# The AccessKey ID of the accepter account
variable "access_key_id" {
  description = "The AccessKey ID for operating your infrastructure"
}
# The AccessKey secret of the accepter account
variable "access_key_secret" {
  description = "The AccessKey Secret for operating your infrastructure"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# Requester VPC ID
variable "local_vpc_id" {
  default = "vpc-t4ns******"
}

# Accepter VPC ID
variable "accepting_vpc_id" {
  default = "vpc-d7ot******"
}

# Create a VPC peering connection
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # Requester VPC ID
  accepting_ali_uid    = var.accepting_uid    # Accepter account ID   
  accepting_region_id  = var.accepting_region # Accepter region
  accepting_vpc_id     = var.accepting_vpc_id # Accepter VPC ID
  bandwidth            = 1024                 # The bandwidth in Mbit/s. You can configure this parameter only when the requester region and the accepter region are different.
  link_type            = "Gold"               # The link type. You can configure this parameter only when the requester region and the accepter region are different.
}

# The accepter accepts the peering connection request
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Configure a route for the requester VPC
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-t4nl******" # The route table bound to the vSwitch where the requester instance is located
  destination_cidrblock = "192.168.0.0/24" # The CIDR block of the accepter VPC
  nexthop_type          = "VpcPeer"        # The next hop is a VPC peering connection
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# Configure a route for the accepter VPC
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-d7od******" # The route table bound to the vSwitch where the accepter instance is located
  destination_cidrblock = "172.16.0.0/12"  # The CIDR block of the requester VPC
  nexthop_type          = "VpcPeer"        # The next hop is a VPC peering connection
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

View metrics

1. Go to the VPC - VPC Peering Connection page. In the top navigation bar, select the region where the VPC is located.

2. Click the icon in the Monitoring column of the target inter-region VPC peering connection. View real-time data for key metrics such as bandwidth usage and packet loss.

Configure alerts (CloudMonitor)

1. Go to the page, and click Create Alert Rule.

2. Configure thresholds for each alert level. When a metric reaches its threshold, notifications are automatically sent to the Alert Contact Group.

3. To view past alerts, click Alert History.

4. To Modify, Disable, or Delete a rule, use the options in the Actions column.