Virtual Private Cloud：高可用虛擬IP（HaVip）

控制台

API

• 調用CreateHaVip建立 HaVip。

• 調用AssociateHaVip綁定 HaVip 和 ECS 執行個體或彈性網卡。

• 調用UnassociateHaVip解除綁定 HaVip 和 ECS 執行個體或彈性網卡。

• 調用DeleteHaVip刪除 HaVip。

Terraform

Resource：alicloud_havip、alicloud_havip_attachment、alicloud_instance、alicloud_security_group、alicloud_security_group_rule

# 指定建立HaVip的地區
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定VPC的ID
variable "vpc_id" {
  default = "vpc-bp1k******" # 修改為VPC的實際ID
}

# 指定交換器ID
variable "vswitch_id" {
  default = "vsw-bp1y******" # 修改為交換器的實際ID
}

# 指定執行個體規格
variable "instance_type" {
  default = "ecs.e-c1m1.large"
}

# 指定鏡像ID
variable "image_id" {
  default = "aliyun_3_x64_20G_alibase_20221102.vhd"
}

# 建立HaVip
resource "alicloud_havip" "test_havip" {
  ha_vip_name = "test_havip_name"
  vswitch_id  = var.vswitch_id
  ip_address  = "192.168.0.24" # 從交換器網段內，指定HaVip的IP地址；若不指定，將由系統分配
}

# 建立安全性群組
resource "alicloud_security_group" "test_security_group" {
  security_group_name = "test_security_group_name"
  vpc_id              = var.vpc_id
}

# 建立安全性群組規則，需根據實際流量調整協議、訪問來源與連接埠。
resource "alicloud_security_group_rule" "allow_vpc_tcp" {
  type              = "ingress"
  ip_protocol       = "tcp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "8000/8000"
  priority          = 1
  security_group_id = alicloud_security_group.test_security_group.id
  cidr_ip           = "192.168.0.0/24"
}

# 建立主伺服器 
resource "alicloud_instance" "test_master_instance" {
  instance_name        = "test_master_instance_name"
  vswitch_id           = var.vswitch_id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.test_security_group.id]
  user_data = base64encode(<<-EOT
    #!/bin/sh
    yum install keepalived -y

    printf '! Configuration File for keepalived
    vrrp_instance VI_1 {
        state MASTER            # 設定為主執行個體
        interface eth0          # 綁定VIP的網卡，本樣本配置為eth0  
        virtual_router_id 51    # 主備叢集的virtual_router_id；同一VPC下的不同主備叢集需要配置不同的virtual_router_id
        nopreempt               # 設定非搶佔模式
        priority 100            # 設定優先權，數字越大，優先順序越高；本樣本配置優先順序為100，將本執行個體設定為主執行個體
        advert_int 1            # 心跳報文發送間隔，單位為秒。設定過小，易受網路抖動影響，可能發生頻繁倒換和暫時雙主（即腦裂）。設定過大，可能導致主執行個體故障後，主備切換時間長。
        authentication {
            auth_type PASS
            auth_pass 1111
        }
        unicast_src_ip 192.168.0.25     # 本執行個體的私網IP地址，本樣本配置為192.168.0.25
        unicast_peer {
            192.168.0.26                # 對端執行個體的私網IP地址，本樣本配置為192.168.0.26；如有多台備用ECS執行個體，需聲明所有對端執行個體的IP。每個地址單獨佔一行，無需逗號或其他分隔字元。
        }
        virtual_ipaddress {
            192.168.0.24                # 虛擬IP地址，配置為HaVip的IP地址，本樣本為192.168.0.24
        }   
        garp_master_delay 1             # 當切為主執行個體後多久更新ARP緩衝，單位為秒 
        garp_master_refresh 5           # 發送ARP報文的時間間隔，單位為秒 

        track_interface {
            eth0                        # 綁定VIP的網卡，本樣本配置為eth0
        }
    }' > /etc/keepalived/keepalived.conf
    systemctl start keepalived
  EOT
  )                                           # 指定主伺服器的初始化指令碼，為主伺服器安裝keepalived
  private_ip           = "192.168.0.25"       # 指定主伺服器的私網IP
  instance_charge_type = "PostPaid"           # 指定付費類型為隨用隨付
  spot_strategy        = "SpotWithPriceLimit" # 設定上限價格的搶佔式執行個體
}

# 建立備伺服器 
resource "alicloud_instance" "test_backup_instance" {
  instance_name        = "test_backup_instance_name"
  vswitch_id           = var.vswitch_id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.test_security_group.id]
  user_data = base64encode(<<-EOT
    #!/bin/sh
    yum install keepalived -y

    printf '! Configuration File for keepalived
    vrrp_instance VI_1 {
        state BACKUP            # 設定為備執行個體
        interface eth0          # 綁定VIP的網卡，本樣本配置為eth0  
        virtual_router_id 51    # 主備叢集的virtual_router_id；同一VPC下的不同主備叢集需要配置不同的virtual_router_id
        nopreempt               # 設定非搶佔模式
        priority 10             # 設定優先權，數字越大，優先順序越高；本樣本配置優先順序為10，將本執行個體設定為備執行個體
        advert_int 1            # 心跳報文發送間隔，單位為秒。設定過小，易受網路抖動影響，可能發生頻繁倒換和暫時雙主（即腦裂）。設定過大，可能導致主執行個體故障後，主備切換時間長
        authentication {
            auth_type PASS
            auth_pass 1111
        }
        unicast_src_ip 192.168.0.26   # 本執行個體的私網IP地址，本樣本配置為192.168.0.26
        unicast_peer {
            192.168.0.25          # 對端執行個體的私網IP地址，本樣本配置為192.168.0.25。需聲明所有對端執行個體的IP。每個地址單獨佔一行，無需逗號或其他分隔字元。
        }
        virtual_ipaddress {
            192.168.0.24          # 虛擬IP地址，配置為HaVip的IP地址，本樣本為192.168.0.24 
        }    
        garp_master_delay 1       # 當切為主執行個體後多久更新ARP緩衝，單位為秒 
        garp_master_refresh 5     # 發送ARP報文的時間間隔，單位為秒 

        track_interface {
            eth0                  # 綁定VIP的網卡，本樣本配置為eth0
        }
    }' > /etc/keepalived/keepalived.conf
    systemctl start keepalived
  EOT
  )                                           # 指定備伺服器的初始化指令碼，為備伺服器安裝keepalived
  private_ip           = "192.168.0.26"       # 指定備伺服器的私網IP 
  instance_charge_type = "PostPaid"           # 指定付費類型為隨用隨付
  spot_strategy        = "SpotWithPriceLimit" # 設定上限價格的搶佔式執行個體
}

# 綁定主伺服器
resource "alicloud_havip_attachment" "test_havip_attachment" {
  ha_vip_id   = alicloud_havip.test_havip.id
  instance_id = alicloud_instance.test_master_instance.id # 指定HaVip關聯的執行個體ID
}

# 綁定備伺服器
resource "alicloud_havip_attachment" "test_havip_attachment_new" {
  ha_vip_id   = alicloud_havip.test_havip.id
  instance_id = alicloud_instance.test_backup_instance.id # 指定HaVip關聯的執行個體ID
}

控制台

API

綁定 EIP 前，確保已調用AllocateEipAddress建立 EIP。

• 調用AssociateEipAddress綁定 HaVip 和 EIP。

• 調用UnassociateEipAddress解除綁定 HaVip 和 EIP。

Terraform

Resource：alicloud_eip_address、alicloud_eip_association

# 指定HaVip所在地區 
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定HaVip的ID
variable "havip_id" {
  default = "havip-8vb0******"  # 修改為HaVip的實際ID
}

# 建立EIP
resource "alicloud_eip_address" "test_eip" {
  address_name = "test_eip_name"
  isp          = "BGP"
  netmode      = "public"
  bandwidth    = "1"
  payment_type = "PayAsYouGo"
}

# 綁定EIP
resource "alicloud_eip_association" "test_eip_havip_association" {
  allocation_id = alicloud_eip_address.test_eip.id
  instance_type = "HAVIP"
  instance_id   = var.havip_id # 指定HaVip的ID
}