Virtual Private Cloud:VPC ピアリング接続

ピアリング接続の作成

1. CreateVpcPeerConnection を呼び出して、VPC ピアリング接続を作成します。

2. 2 つの VPC が異なるアカウントに属している場合、リクエスト先アカウントの所有者は AcceptVpcPeerConnection を呼び出して VPC ピアリング接続を承諾する必要があります。

   リクエスト先は RejectVpcPeerConnection を呼び出して VPC ピアリング接続を拒否できます。

3. 両方の VPC の所有者は GetVpcPeerConnectionAttribute を呼び出して、2 つの VPC の CIDR ブロックをクエリする必要があります。

4. 両方の VPC の所有者は CreateRouteEntry を呼び出して、ピアリング接続を指すルートを作成する必要があります。

リージョン間ピアリング接続の変更

ModifyVpcPeerConnection を呼び出して、リージョン間 VPC ピアリング接続の帯域幅またはリンクタイプを変更します。

ピアリング接続の削除

• DeleteRouteEntry を呼び出して、ピアリング接続を指すルートを削除します。

• DeleteVpcPeerConnection を呼び出して、VPC ピアリング接続を削除します。

パス解析

パス解析を使用して接続性を確認するには、以下の API 操作を順番に呼び出します。

1. CreateNetworkPath - ネットワーク解析パスの作成

2. CreateNetworkReachableAnalysis - ネットワーク到達可能性解析タスクの作成

3. GetNetworkReachableAnalysis - ネットワーク到達可能性解析タスクの結果の取得

同一アカウントのピアリング接続

リソース：alicloud_vpc_peer_connection、alicloud_route_entry

データソース：alicloud_account

# VPC が属するアカウント
data "alicloud_account" "default" {}

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # リクエスト元 VPC があるリージョン
}

provider "alicloud" {
  alias  = "accepting"
  region = "cn-beijing" # リクエスト先 VPC のリージョン。リクエスト元 VPC のリージョンと同じでもかまいません。リクエスト先 VPC のリージョンに基づいてこのパラメーターを設定します。
}

# リクエスト元 VPC ID
variable "local_vpc_id" {
  default = "vpc-bp1c******"
}

# リクエスト先 VPC ID
variable "accepting_vpc_id" {
  default = "vpc-2zev******"
}

# VPC ピアリング接続の作成
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id                 # リクエスト元 VPC ID
  accepting_ali_uid    = data.alicloud_account.default.id # リクエスト先アカウント ID   
  accepting_region_id  = "cn-beijing"                     # リクエスト先 VPC があるリージョン
  accepting_vpc_id     = var.accepting_vpc_id             # リクエスト先 VPC ID
  bandwidth            = 1024                             # 帯域幅 (Mbit/s)。リクエスト元リージョンとリクエスト先リージョンが異なる場合にのみ設定できます。
  link_type            = "Gold"                           # リンクタイプ。リクエスト元リージョンとリクエスト先リージョンが異なる場合にのみ設定できます。
}

# リクエスト元 VPC のルートを設定
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-bp1a******"            # リクエスト元インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "172.16.0.0/12"             # リクエスト先 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"                   # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# リクエスト先 VPC のルートを設定
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.accepting
  route_table_id        = "vtb-2ze1******"            # リクエスト先インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "10.0.0.0/8"                # リクエスト元 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"                   # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

クロスアカウントのピアリング接続

リソース：alicloud_vpc_peer_connection、alicloud_vpc_peer_connection_accepter、alicloud_route_entry

provider "alicloud" {
  alias  = "local"
  region = "cn-hangzhou" # リクエスト元 VPC のリージョン 
}

# リクエスト先 VPC のリージョン。リクエスト元 VPC のリージョンと同じでもかまいません。リクエスト先 VPC のリージョンに基づいて設定する必要があります。
variable "accepting_region" {
  default = "cn-beijing"
}

# リクエスト先アカウント
variable "accepting_uid" {
  default = "1234******"
}

# リクエスト先アカウントの AccessKey ID
variable "access_key_id" {
  description = "インフラストラクチャを操作するための AccessKey ID"
}
# リクエスト先アカウントの AccessKey Secret
variable "access_key_secret" {
  description = "インフラストラクチャを操作するための AccessKey Secret"
}

provider "alicloud" {
  alias      = "acceptor"
  region     = var.accepting_region
  access_key = var.access_key_id
  secret_key = var.access_key_secret
}

# リクエスト元 VPC ID
variable "local_vpc_id" {
  default = "vpc-2ze0******"
}

# リクエスト先 VPC ID
variable "accepting_vpc_id" {
  default = "vpc-wz9e******"
}

# VPC ピアリング接続の作成
resource "alicloud_vpc_peer_connection" "example_peer_connection" {
  provider             = alicloud.local
  peer_connection_name = "example_peer_connection_name"
  vpc_id               = var.local_vpc_id     # リクエスト元 VPC ID
  accepting_ali_uid    = var.accepting_uid    # リクエスト先アカウント ID   
  accepting_region_id  = var.accepting_region # リクエスト先リージョン
  accepting_vpc_id     = var.accepting_vpc_id # リクエスト先 VPC ID
  bandwidth            = 1024                 # 帯域幅 (Mbit/s)。リクエスト元リージョンとリクエスト先リージョンが異なる場合にのみ設定できます。
  link_type            = "Gold"               # リンクタイプ。リクエスト元リージョンとリクエスト先リージョンが異なる場合にのみ設定できます。
}

# リクエスト先がピアリング接続リクエストを承諾
resource "alicloud_vpc_peer_connection_accepter" "example_peer_connection_accepter" {
  provider    = alicloud.acceptor
  instance_id = alicloud_vpc_peer_connection.example_peer_connection.id
}

# リクエスト元 VPC のルートを設定
resource "alicloud_route_entry" "example_local_route" {
  provider              = alicloud.local
  route_table_id        = "vtb-2zel******" # リクエスト元インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "192.168.0.0/24" # リクエスト先 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"        # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

# リクエスト先 VPC のルートを設定
resource "alicloud_route_entry" "example_acceptor_route" {
  provider              = alicloud.acceptor
  route_table_id        = "vtb-wz95******" # リクエスト先インスタンスがある vSwitch にバインドされたルートテーブル
  destination_cidrblock = "172.16.0.0/12"  # リクエスト元 VPC の CIDR ブロック
  nexthop_type          = "VpcPeer"        # ネクストホップは VPC ピアリング接続
  nexthop_id            = alicloud_vpc_peer_connection.example_peer_connection.id
}

ピアリング接続のモニタリング

1. VPC - VPC ピアリング接続ページに移動します。トップナビゲーションバーで、VPC があるリージョンを選択します。

2. 対象のリージョン間 VPC ピアリング接続の [モニタリング] 列にある アイコンをクリックして、帯域幅やパケット損失などのメトリックを表示します。

CloudMonitor アラート

1. CloudMonitor - アラートルールページに移動し、+ アラートルールの作成 をクリックします。

2. 各アラートレベルのしきい値を設定します。メトリックがしきい値に達すると、指定された [アラートグループ] にアラート通知が送信されます。アラートルールの [アクション] 列の [アラート履歴] をクリックして、アラートのタイムラインを表示します。

3. アラートルールの [アクション] 列で、ルールを [変更]、[無効化]、または [削除] できます。